42、理解RANKX函数

RANKX函数是DAX函数中的核心函数之一，可以用来对数据进行排名，虽然有些窗口函数也可以实现排名，但RANKX仍然是必须要掌握的函数。

语法和作用

语法：

RANKX(table, expression[, value[, order[, ties]]])

作用：针对 table 参数中每一行，返回某个数值在数值列表中的排名。

参数说明：

1、Table，在外部计值环境计值，接受所有返回表的表函数。

2、Expression，在外部计值环境与Table参数的行上下文里计值，为Table的每一行计算一个标量值，该标量值可以是文本或数值，用来确定参与排名的值列表。

3、Value，可选参数，在外部计值环境里计值，结果为标量值，用于指定需要在值列表里排名的值。若省略，则默认使用第二参数的表达式来计算，但计值环境为外部计值环境。

4、Order，可选参数，用于指定升序或降序，降序为：0或DESC，升序为：1或ASC，默认降序排列。

5、Ties，可选参数，用于指定排名的样式，紧凑格式：DENSE，松散样式：SKIP，默认为SKIP。

辅助理解的例子

1、RANKX函数进行排名的算法原理如下图所示：

2、RANKX函数的作用可以用其他函数来实现，其等价写法如下：

所用到的度量值如下：

RANKX-SKIP-降序 = RANKX(ALL('产品'[产品名称]),[销售金额])

RANKX-DENSE-降序 = RANKX(ALL('产品'[产品名称]),[销售金额],,DESC,Dense)

等价写法-SKIP-降序 = 
VAR tTable = ADDCOLUMNS(ALL('产品'[产品名称]),"Sales",[销售金额])
VAR CurrentValue = [销售金额]
RETURN
COUNTROWS(
    FILTER(
        tTable,
        [Sales]>CurrentValue
    )
)+1

等价写法-DENSE-降序 = 
VAR tTable = SELECTCOLUMNS(ALL('产品'[产品名称]),"Sales",[销售金额])
VAR CurrentValue = [销售金额]
RETURN
COUNTROWS(
    FILTER(
        DISTINCT(tTable),
        [Sales]>CurrentValue
    )
)+1

上面给出的是降序排列的等价写法，升序排列只需要将FILTER第二参数的大于号改成小于号即可。

3、RANKX函数除了可以用于排名外，还可以用来进行分组，例如：划分年龄区间、价格区间等等，具体如下图：

所用的计算列表达式如下：

SWITCH-利润区间 = 
SWITCH( TRUE(),
    '产品'[单位利润]<11    ,    "1-10",
    '产品'[单位利润]<21    ,    "11-20",
    '产品'[单位利润]<31    ,    "21-30",
    '产品'[单位利润]<41    ,    "31-40",
    '产品'[单位利润]<51    ,    "41-50",
    "大于50"
)

IF-利润区间 = 
       IF('产品'[单位利润]<11,"1-10",
       IF('产品'[单位利润]<21,"11-20",
       IF('产品'[单位利润]<31,"21-30",
       IF('产品'[单位利润]<41,"31-40",
       IF('产品'[单位利润]<51,"41-50","大于50")))))

RANKX-利润区间 = 
VAR RankNum =RANKX({1,11,21,31,41,51},[value],'产品'[单位利润])
RETURN
IF(RankNum = 1,"大于50",(6-RankNum)*10+1 & "-" & (7-RankNum)*10)

其中，RANKX函数只需要三行代码就可以完成分组，是不是非常凶残啊，其中的逻辑还是很好理解的，大家自行体会，就不再赘述。

4、需要注意，RANKX函数的第三参数是可以省略的，当省略第三参数时将默认使用第二参数的表达式，但要注意，省略时表达式虽然一致，但计值环境却是不一致的。第二参数的计值环境是在外部计值环境与Table参数的行上下文里计值的，而第三参数却仅在外部计值环境中计算。

总结

RANKX函数的所有内容都在上面了，虽然没有详细介绍，但只要搞懂了上面给出的算法原理和等价写法，那么掌握RANKX函数的计值流程应该也没问题。